Ein Thermometer für alle Fälle

Ein Thermometer für alle Fälle

Experiment	Ein Thermometer für alle Fälle
Category	Arduino library experiments
Used sensors	DS18B20

Der DS18B20 ist ein sehr weit verbreiteter Temperatursensor. Dank des OneWire-Buses hat der Sensor nur drei Anschlüsse und kann extrem einfach mit einem Mikrocontroller verbunden werden. Zusätzlich wird noch ein 4k7-Widerstand benötigt, um den OneWire-Bus zu stabilisieren. Um den Temperatursensor schön kompakt zu gestalten, wurde auf dem Bild oben ein ESP32-C3 verwendet. Der kann nicht so viel wie der normale ESP32, muss es hier aber auch nicht.

Aufbau

Der Temperatursensor liefert seine Daten über den OneWire-Bus: 3V3 – Vin, Gnd – Gnd, 2 - Datenbus. Der Datenbus Pin 2 ist, wie oben beschrieben, über Pullup-widerstand auf "High" hochgezogen. Die Bluetooth-Antenne wurde einfach abgeknipst, für kurze Entfernungen reicht es mit dem Rest den Rest den Anschlusskabels. Achtung: Das Koaxialkabel muss so abgekniffen werden, dass nichts kurzgeschlossen wird!

Ist alles verlötet und funktioniert, kann es kompakt mit Schrupfschlauch eingepackt werden. Nicht vergessen, den dünneren Schrupfschlauch für die Zugentlastung und Knickschutz vor dem Löten übers Kabel zu schieben...

Programmierung

Der ESP32 wird über die Arduino IDE programmiert. Es müssen die Definitionen für den ESP32 und die phyphox-Bibliothek installiert sein. Siehe dazu das Video unter Category: Arduino library experiments.

Es ist darauf zu achten, dass jeder ESP32 eine eigene Kennung hat (diese wird in PhyphoxBLE::start("Thermometer_01") festgelegt). Anschließend kann über das Plus-Symbol in phyphox ein Bluetooth-Experiment hinzugefügt werden, das Experiment wird dann automatisch geladen.

/* ////////////////////////////////////////////////////////////////////////////
  phyphox ESP32 for temperature sensor DS18B20
  TODO: -
  AUTHOR: Torsten Klaffs
  LICENSE: CC0
*/

#include <phyphoxBle.h>
#include <OneWire.h>            // listet in library manager
#include <DallasTemperature.h>  // listet in library manager
#define ONE_WIRE_BUS 2          // sensor is connected to GPIO2

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);


void setup(void) {
  // Start the BLE server, argument is visible name
  PhyphoxBLE::start("Thermometer 01");

  //Experiment
  PhyphoxBleExperiment thermometer;
  thermometer.setTitle("Thermometer");
  thermometer.setCategory("ESP32 Experiment");
  thermometer.setDescription("Plot the Temperature over time. Used togehter with an DS18B20");

  // View
  PhyphoxBleExperiment::View view;
  view.setLabel("Raw data");

  // Graph
  PhyphoxBleExperiment::Graph tempGraph;
  tempGraph.setLabel("Temperatur");
  tempGraph.setUnitX("s");
  tempGraph.setUnitY("°C");
  tempGraph.setLabelX("time");
  tempGraph.setLabelY("Theta");
  tempGraph.setChannel(0, 1);

  view.addElement(tempGraph);              // attach graph to view
  thermometer.addView(view);               // attach view to experiment
  PhyphoxBLE::addExperiment(thermometer);  // attach experiment to server

  sensors.begin();
}

void loop(void) { 
  sensors.requestTemperatures();         // request all temperatures
  float T = sensors.getTempCByIndex(0);  // get temperature with index 0
  PhyphoxBLE::write(T);                  // send temperature to phyphox
  delay(500); // wait 500ms
}